frame-of-mind/src/base-environments/youth_room/youth_room.gd

class_name YouthRoom
extends RoomTemplate

## Used by the room system when this room becomes active
# var is_active: bool = false # Reminder, do not uncomment, this field is inherited from RoomTemplate!

@onready var card_picker: CardPicker = %Picker
@onready var ui: Control = %UI

func start_room():
	%UI.show()
	$logic/PlayerController.process_mode = Node.PROCESS_MODE_INHERIT

	await Main.curtain.open()

	if not Scenes.is_sequence_repeating(Scenes.id.YOUTH_DRAVEN):
		# Play intro scene directly (not triggered by CollectableUi)
		await _play_intro_scene()
	else:
		%LightAnimation.lights_on()

	# Give player control after intro (or immediately if repeating)
	Scenes.player_enable.emit(true)


func _play_intro_scene() -> void:
	# The intro scene is auto-played, not triggered by CollectableUi
	var intro: Interactable = $logic/CeilingInteractable
	await intro.play_story()

	Scenes.end_sequence(Scenes.id.YOUTH_DRAVEN)



func get_ready():
	await get_tree().process_frame

	pull_save_state(State.save_game)

	card_board.board_completed.connect(func():
		save_game.is_childhood_board_complete = true
		save_room())

	card_board.closed.connect(save_room)

	card_picker.cards_picked.connect(card_board.populate_board)

	ui.hide()
	$sfx/distant_rain.play()
	$"sfx/rain on window".play()

	await get_tree().process_frame


func _ready():
	printt(_ready, name)
	super._ready()
	id = State.rooms.YOUTH
	Scenes.scene_finished.connect(_on_scene_finished)



func pull_save_state(save: SaveGame) -> void:
	save_game = save
	save_game.current_room = id

	# Load board state from save first, before overwriting it
	card_board.initialise_from_save(save_game)

	Scenes.started_sequences = save_game.mementos_complete
	Scenes.completed_sequences = save_game.mementos_complete

	# Call parent to restore player position
	super.pull_save_state(save)


func _on_scene_finished(_id: int, _repeat:bool):
	await get_tree().create_timer(3).timeout
	save_room()

func save_room():
	# Update board state before saving
	card_board.save_to_resource(save_game)
	save_game.mementos_complete = Scenes.completed_sequences
	super.save_room()

func prepare_transition():
	save_room()
	$visuals/AnimationPlayer.play("conserve_performance")
	await $visuals/AnimationPlayer.animation_finished
	unload()


## Override to handle scene-specific preparation (chest reveal animation)
func prepare_scene_start(scene_id: Scenes.id, is_repeating: bool) -> void:
	# Only play chest reveal on first playthrough of voice training scene
	if scene_id == Scenes.id.YOUTH_VOICE_TRAINING and not is_repeating:
		await play_chest_reveal()

# Called when voice training scene starts
func play_chest_reveal() -> void:
	$visuals/AnimationPlayer.play("chest_reveal")
	$visuals/SecondaryAnimation.play("chest_reveal")
	await $visuals/SecondaryAnimation.animation_finished


func unload():
	$visuals.queue_free()