class_name YouthRoom
extends RoomTemplate

## Used by the room system when this room becomes active
# var is_active: bool = false # Reminder, do not uncomment, this field is inherited from RoomTemplate!

@onready var card_picker: CardPicker = %Picker
@onready var ui: Control = %UI

func _ready() -> void:
	id = State.rooms.YOUTH
	super._ready() # UwU, superclass _ready is not called by Godot automatically...


func start_room():
	await super.start_room()

	%UI.show()

	await Main.curtain.open()

	# To start breathing etc.
	%PlayerController.process_mode = PROCESS_MODE_INHERIT

	# Skip intro if already loaded.
	if not Scenes.is_sequence_repeating(Scenes.id.YOUTH_DRAVEN):
		# Play intro scene directly (not triggered by CollectableUi)
		await _play_intro_scene()
	else:
		%LightAnimationPlayer.lights_on()
		%SceneAnimationPlayer.start_soundtrack()

	Scenes.player_enable.emit(true)



func _play_intro_scene() -> void:
	# The intro scene is auto-played, not triggered by CollectableUi
	var intro: Interactable = $logic/CeilingInteractable
	await intro.interact()


func get_ready() -> void:
	await super.get_ready()

	pull_save_state(State.save_game)
	
	card_board.closed.connect(save_room)
	card_board.board_completed.connect(func():
		%DoorInteractable.show()
		save_game.childhood_board_complete = true
		)

	Scenes.scene_finished.connect(_on_scene_finished)
	card_picker.cards_picked.connect(card_board.populate_board)

	ui.hide()
	$sfx/distant_rain.play()
	$"sfx/rain on window".play()


func pull_save_state(save: SaveGame) -> void:
	save_game = save
	save_game.current_room = id

	# Interactions can this way load their correct prompts
	get_tree().call_group("interactables", "pull_save_state")
	
	# Load board state from save first, before overwriting it
	card_board.initialise_from_save(save_game)

	# TODO: These should be deprecated, SaveGame is our source of truth
	Scenes.started_sequences = save_game.mementos_complete
	Scenes.completed_sequences = save_game.mementos_complete

	# Call parent to restore player position
	super.pull_save_state(save)


func _on_scene_finished(_id: int, _repeat:bool):
	await get_tree().create_timer(3).timeout
	save_room()

func save_room():
	# Update board state before saving
	card_board.save_to_resource(save_game)
	save_game.mementos_complete = Scenes.completed_sequences
	super.save_room()


## Override to handle scene-specific preparation (chest reveal animation)
func prepare_scene_start(scene_id: Scenes.id, is_repeating: bool) -> void:
	# Only play chest reveal on first playthrough of voice training scene
	if scene_id == Scenes.id.YOUTH_VOICE_TRAINING and not is_repeating:
		await play_chest_reveal()

# Called when voice training scene starts
func play_chest_reveal() -> void:
	$visuals/AnimationPlayer.play("chest_reveal")
	$visuals/SecondaryAnimation.play("chest_reveal")
	await $visuals/AnimationPlayer.animation_finished


func play_thunder() -> void:
	%RoomAnimationPlayer.play("lightning_and_thunder")