## A dolly tweens all contents to and from two destination points, and to its origin. 
class_name Dolly
extends Node3D

@export var start_arrived : bool = false
@export var pre_arrival_time : float = 10.0
@export var arrival_time : float = 15.0
@export var pre_leave_time : float = 20.0
@export var leave_time : float  = 16.0
@export var post_leave_time : float = 5.0

@onready var origination : Node3D = $Origination
@onready var destination : Node3D = $Destination 

@onready var subway : SubwayTrain = %Subway 


var tween : Tween = null

func _ready() -> void:
	if not start_arrived:
		for child in get_children(true):
			if not child.visible: continue
			child.global_position = origination.global_position
	
	
## One arrival and departure	
func cycle() -> void:
	await arrive()
	await leave()


func arrive() -> void:
	%SubwayTrainAudio.play(0)
	await get_tree().create_timer(16).timeout
	if tween: tween.kill()
	tween = create_tween().set_trans(Tween.TRANS_CIRC).set_ease(Tween.EASE_OUT)
	for child in get_children(true):
		if not child.visible: continue
		tween.parallel().tween_property(child, "global_position", self.global_position, arrival_time)
	await tween.finished
	subway.door_open = true	


func leave() -> void:
	await get_tree().create_timer(pre_leave_time).timeout
	subway.door_open = false
	await get_tree().create_timer(1).timeout
	if tween: tween.kill()
	tween = create_tween().set_trans(Tween.TRANS_QUART).set_ease(Tween.EASE_IN)
	for child in get_children(true):
		if not child.visible: continue
		tween.parallel().tween_property(child, "global_position", destination.global_position, leave_time)
	await tween.finished
	await %SubwayTrainAudio.finished
	for child in get_children(true):
		if not child.visible: continue
		# Warp back
		child.global_position = origination.global_position
	arrive()