frame-of-mind/src/logic-scenes/board/post-it.gd

@tool

extends Area2D
class_name PostIt
var sibling
var wiggle_pos: float = randf_range(-100, 100)
var wiggle_intensity: float = 0
var noise: Noise = FastNoiseLite.new()
var shift_tween
var modulate_tween

@export var text: String = "" :
    set (value):
        if is_inside_tree() or Engine.is_editor_hint():
            $Content/Label.text = value
            $Content/BackgroundSprite.frame = text.hash() % $Content/BackgroundSprite.sprite_frames.get_frame_count($Content/BackgroundSprite.animation)
        text = value

@export var shift_by: Vector2 = Vector2(-32, 0)
@export_color_no_alpha var highlight_color: Color = Color(1.5, 1.5, 1.5)
@export var highlighted: bool = false:
    set(highlight):
        if highlight != highlighted:
            highlighted = highlight

            if is_inside_tree() and is_node_ready():
                if modulate_tween: modulate_tween.kill()
                if shift_tween: shift_tween.kill()
                if highlighted:
                    modulate_tween = get_tree().create_tween()
                    modulate_tween.tween_property(self, "modulate", highlight_color, 0.1)
                    shift_tween = get_tree().create_tween()
                    shift_tween.tween_property($Content, "position", shift_by, 0.2)
                else:
                    modulate_tween = get_tree().create_tween()
                    modulate_tween.tween_property(self, "modulate", Color(1, 1, 1), 0.3)
                    shift_tween = get_tree().create_tween()
                    shift_tween.tween_property($Content, "position", Vector2.ZERO, 0.5)
            else:
                if highlighted:
                    modulate = Color(1, 1, 1)
                    wiggle_intensity = 1
                else:
                    modulate = Color(1, 1, 1)
                    wiggle_intensity = 0

@export var voice_line: AudioStream = null
@export var is_dragable: bool = false
var base_rotation = null
var base_scale = null
var is_dragged = false

func _ready() -> void:
    
    self.set_meta("type", "post-it")  # set type information to find out if this node is a post-it
    base_rotation = rotation
    base_scale = scale
    
    $Content/Label.text = self.text
    $Content/BackgroundSprite.frame = text.hash() % $Content/BackgroundSprite.sprite_frames.get_frame_count($Content/BackgroundSprite.animation)
    

func replace_with(postit: PostIt):
    self.text = postit.text
    self.voice_line = postit.voice_line
    self.sibling = postit.sibling

func _process(delta: float) -> void:
    _move_post_it()


func _on_focus_entered():
    print(self, "is focused")

func _on_focus_exited():
    print(self, "is not focused")

func _on_mouse_entered():
    if not Input.is_action_pressed("mouse_left"):
        highlighted = true
        if "handle_hover" in owner:
            owner.handle_hover(self)

func _on_mouse_exited():
    highlighted = false

func _on_input_event(viewport, event, shape_idx):
    if event is InputEventMouseMotion:
        _move_post_it()
        
    if event is InputEventMouseButton:
        if event.button_index == MOUSE_BUTTON_LEFT:
            if is_dragable and "handle_mouse_button" in owner:
                owner.handle_mouse_button(self, event)

func _move_post_it():
    if is_dragged:
        position += get_viewport().get_mouse_position() - position