winter-tales/GameObjects/Roof/Roof.gdshader

// NOTE: Shader automatically converted from Godot Engine 4.5.stable.mono's StandardMaterial3D.

shader_type spatial;
render_mode blend_mix, depth_draw_opaque, cull_back, diffuse_burley, specular_schlick_ggx;

#include "res://addons/rokojori_action_library/Runtime/Shading/Library/Math.gdshaderinc"
#include "res://addons/rokojori_action_library/Runtime/Shading/Library/Transform.gdshaderinc"

uniform vec4 albedo : source_color;
uniform sampler2D texture_albedo : source_color, filter_nearest_mipmap_anisotropic, repeat_enable;
uniform ivec2 albedo_texture_size;
uniform float point_size : hint_range(0.1, 128.0, 0.1);

uniform float roughness : hint_range(0.0, 1.0);
uniform sampler2D texture_metallic : hint_default_white, filter_nearest_mipmap_anisotropic, repeat_enable;
uniform vec4 metallic_texture_channel;
uniform sampler2D texture_roughness : hint_roughness_r, filter_nearest_mipmap_anisotropic, repeat_enable;

uniform float specular : hint_range(0.0, 1.0, 0.01);
uniform float metallic : hint_range(0.0, 1.0, 0.01);

uniform sampler2D texture_normal : hint_roughness_normal, filter_nearest_mipmap_anisotropic, repeat_enable;
uniform float normal_scale : hint_range(-16.0, 16.0);

uniform vec3 uv1_scale;
uniform vec3 uv1_offset;

// [ SNOW ]
group_uniforms snow;
uniform float maxSnowV = 0.8;
uniform float topSnowOpacity = 1;
uniform float bottomSnowOpacity = 0;
uniform float snowWaveFrequency = 2;
uniform float snowWaveFrequencySeedAmount = 1;
uniform float snowWaveAmount = 0;
uniform float snowWaveSeedStrength = 1;
uniform float snowNormalOffset = -0.5;
uniform float snowNormalScale = -0.5;

uniform float snowRoughness = 0.3;
uniform float snowNormalMixAmount = 0.5;
uniform float snowAlbedo = 1.0;
global uniform float globalSnowAmount;

varying float worldSeedXZ;
varying float worldNormalAmount;

void vertex() 
{
	UV = UV * uv1_scale.xy + uv1_offset.xy;
  worldSeedXZ = fract( 123.94444 * fract( NODE_POSITION_WORLD.x * 42130.323 ) + 3.35 * fract( NODE_POSITION_WORLD.z * 13435.124 ) );

  vec3 worldNormal = localToWorldDirection( NORMAL, MODEL_MATRIX );
  worldNormalAmount = clamp01( snowNormalScale * ( dot( worldNormal, vec3( 0, 1, 0 ) ) + snowNormalOffset ) );
}

void fragment() 
{
  vec2 tSize = vec2( textureSize( texture_albedo, 0 ) );
  vec2 quantizedUV = round( UV * tSize ) / tSize;
  float snowV = mix( 0.0, maxSnowV, globalSnowAmount );
  float vOffset = sin( quantizedUV.x * ( snowWaveFrequency + ( worldSeedXZ * 2.0 - 1.0 ) * snowWaveFrequencySeedAmount ) + worldSeedXZ * snowWaveSeedStrength ) * snowWaveAmount;
  float inSnow = mapClamped( quantizedUV.y + vOffset, 0.0, snowV, 1.0, 0.0 );
  float snowCoverage = mix( bottomSnowOpacity, topSnowOpacity, inSnow );
  snowCoverage = max( snowCoverage, worldNormalAmount );
  snowCoverage *= mapClamped( globalSnowAmount, 0, 0.4, 0, 1.0 );

	vec2 base_uv = UV;

	vec4 albedo_tex = texture(texture_albedo, base_uv);
	ALBEDO = albedo.rgb * albedo_tex.rgb;

  ALBEDO = mix( ALBEDO, vec3( snowAlbedo ), snowCoverage );

	float metallic_tex = dot(texture(texture_metallic, base_uv), metallic_texture_channel);
	METALLIC = metallic_tex * metallic;
	SPECULAR = specular;

	vec4 roughness_texture_channel = vec4(1.0, 0.0, 0.0, 0.0);
	float roughness_tex = dot(texture(texture_roughness, base_uv), roughness_texture_channel);
	ROUGHNESS = roughness_tex * roughness;
  ROUGHNESS = mix( ROUGHNESS, snowRoughness, snowCoverage );

	// Normal Map: Enabled
	NORMAL_MAP = texture(texture_normal, base_uv).rgb;
  NORMAL_MAP = mix( NORMAL_MAP, vec3( 0.5 ), snowCoverage * snowNormalMixAmount );
	NORMAL_MAP_DEPTH = normal_scale;
}